+float newlight_specular( vec3 wnormal, vec3 dir, vec3 halfview, float exponent )
+{
+ vec3 specdir = reflect( -dir, wnormal );
+ return pow(max(dot( halfview, specdir ), 0.0), exponent);
+}
+
+vec3 scene_apply_fog( vec3 vfrag, vec3 colour, float fdist )
+{
+ float dist = pow(fdist*0.0010,0.78);
+ return mix( vfrag, colour, min( 1.0, dist ) );
+}
+
+vec3 rand33(vec3 p3)
+{
+ p3 = fract(p3 * vec3(.1031, .1030, .0973));
+ p3 += dot(p3, p3.yxz+33.33);
+ return fract((p3.xxy + p3.yxx)*p3.zyx);
+}
+
+vec3 scene_calculate_light( int light_index,
+ vec3 halfview, vec3 co, vec3 normal )
+{
+ vec4 light_colour = texelFetch( uLightsArray, light_index+0 );
+ vec4 light_co = texelFetch( uLightsArray, light_index+1 );
+ vec4 light_dir = texelFetch( uLightsArray, light_index+2 );
+
+ vec3 light_delta = light_co.xyz-co;
+ float dist2 = dot(light_delta,light_delta);
+
+ light_delta = normalize( light_delta );
+
+ float quadratic = dist2*100.0;
+ float attenuation = 1.0f/( 1.0f + quadratic );
+ attenuation *= max( dot( light_delta, normal ), 0.0 );
+
+ float falloff = max( 0.0, 1.0-(dist2*light_co.w) );
+
+ if( light_dir.w < 0.999999 ){
+ float spot_theta = max( 0.0, dot( light_delta, -light_dir.xyz ) );
+ falloff *= max( 0.0, (spot_theta - light_dir.w) / (1.0-light_dir.w) );
+ }
+
+ return light_colour.rgb * attenuation * falloff
+ * step( g_day_phase, light_colour.w );
+}
+
+vec3 scene_calculate_packed_light_patch( uint packed_index,
+ vec3 halfview, vec3 co, vec3 normal )
+{
+ uint light_count = packed_index & 0x3u;
+
+ vec3 l = vec3(0.0);
+
+ if( light_count >= 1u ){
+ int index_0 = int( ((packed_index >> 2u) & 0x3ffu) * 3u );
+ int index_1 = int( ((packed_index >> 12u) & 0x3ffu) * 3u );
+ int index_2 = int( ((packed_index >> 22u) & 0x3ffu) * 3u );
+
+ l += scene_calculate_light( index_0, halfview, co, normal );
+
+ if( light_count >= 2u ){
+ l += scene_calculate_light( index_1, halfview, co, normal );
+
+ if( light_count >= 3u ){
+ l += scene_calculate_light( index_2, halfview, co, normal );
+ }
+ }
+ }
+
+ return l;
+}
+
+vec3 world_compute_lighting( vec3 diffuse, vec3 normal, vec3 co,
+ float light_mask )
+{
+ if( g_light_preview == 1 )
+ diffuse = vec3(0.75);
+
+ // Lighting
+ vec3 halfview = uCamera - co;
+ float fdist = length(halfview);
+ halfview /= fdist;
+
+ float world_shadow = newlight_compute_sun_shadow( g_sun_dir.xyz
+ * (1.0/(max(g_sun_dir.y,0.0)+0.2)) );
+
+ vec3 total_light = clearskies_lighting(
+ normal, min( light_mask, world_shadow ), halfview );
+
+ vec3 cube_coord = (co - g_cube_min.xyz) * g_cube_inv_range.xyz;
+ cube_coord = floor( cube_coord );
+
+ if( g_debug_indices == 1 )
+ {
+ return rand33(cube_coord);
+ }
+
+ if( g_debug_complexity == 1 )
+ {
+ ivec3 coord = ivec3( cube_coord );
+ uvec4 index_sample = texelFetch( uLightsIndex, coord, 0 );
+
+ uint light_count = (index_sample.x & 0x3u) + (index_sample.y & 0x3u);
+ return vec3( float(light_count)*(1.0/6.0), 0.0, 0.5 );
+ }
+
+ // FIXME: this coord should absolutely must be clamped!
+
+ ivec3 coord = ivec3( cube_coord );
+ uvec4 index_sample = texelFetch( uLightsIndex, coord, 0 );
+
+ total_light +=
+ scene_calculate_packed_light_patch( index_sample.x,
+ halfview, co, normal )
+ * light_mask;
+ total_light +=
+ scene_calculate_packed_light_patch( index_sample.y,
+ halfview, co, normal )
+ * light_mask;
+
+ // Take a section of the sky function to give us a matching fog colour
+
+ vec3 fog_colour = clearskies_ambient( -halfview );
+ float sun_theta = dot( -halfview, g_sun_dir.xyz );
+ float sun_size = max( 0.0, sun_theta * 0.5 + 0.5 );
+ float sun_shape = sun_size * max(g_sun_dir.y,0.0) * 0.5;
+
+ vec3 sun_colour = mix( vec3(1.0), g_sunset_colour.rgb, g_sunset_phase*0.5 );
+ sun_colour *= sun_shape;
+
+ fog_colour += sun_colour;
+ return scene_apply_fog( diffuse * total_light, fog_colour, fdist );
+}