#include "water_ref.glsl"

out vec4 FragColor;

uniform sampler2D uTexMain;
uniform sampler2D uTexDudv;
uniform sampler2D uTexDepth;
uniform sampler2D uTexBack;

uniform vec2 uInvRes;
uniform float uTime;

uniform vec3 uCamera;
uniform float uSurfaceY;

in vec4 aUv;
in vec3 aCo;
in float aDepth;

void main()
{
   // Create texture coords
   vec2 ssuv = gl_FragCoord.xy*uInvRes;
   
   // Surface colour composite
   float depthvalue = texture( uTexDepth, aUv.zw ).r;

   vec4 dudva = texture(uTexDudv, aUv.xy + vec2(uTime*0.008,uTime*0.006))-0.5;
   vec4 dudvb = texture(uTexDudv, aUv.xy*7.0-vec2(uTime*0.003,uTime*0.03))-0.5;

   vec3 surfnorm = dudva.rgb + dudvb.rgb;
   surfnorm = normalize(vec3(0.0,1.0,0.0) + dudva.xyz*0.4 + dudvb.xyz*0.1);
   
   // Foam
   float fband = fract( aCo.z*0.02+uTime*0.1+depthvalue*10.0 );
   fband = step( fband+dudva.a*0.8, 0.3 ) * max((1.0-depthvalue*4.0),0.0);

   // Lighting
   vec3 halfview = -normalize( aCo-uCamera );

   // Sample textures
   vec4 above = texture( uTexMain, ssuv+ surfnorm.xz*0.2 );
   vec4 beneath = texture( uTexBack, ssuv );

   // Fog
   //vec4 horizon = vec4( 0.5, 0.6, 0.9, 1.0 );
   vec4 horizon = vec4( 0.7,0.8,0.88, 1.0 );
   float fdist = pow(length( aCo.xz-uCamera.xz ) * 0.00047, 2.6);

   // Composite
   vec4 vsurface = water_surf( halfview, surfnorm, depthvalue, beneath, above );
   vsurface.a -= fdist;
   FragColor = mix( vsurface, vec4(1.0,1.0,1.0,0.5), fband );
}