uniform sampler2D uTexGarbage;
uniform sampler2D uTexGradients;
uniform vec3 uCamera;

in vec4 aColour;
in vec2 aUv;
in vec3 aNorm;
in vec3 aCo;
in vec3 aWorldCo;

#include "common_world.glsl"
#include "motion_vectors_fs.glsl"

void main()
{
   compute_motion_vectors();

   vec3 vfrag = vec3(0.5,0.5,0.5);

   // ws modulation
   vec4 wgarbage = vec4(0.5,0.5,0.5,1.0);//texture( uTexGarbage, aCo.xz * 0.160 );
   
   // Creating normal patches
   vec3 modnorm = (wgarbage.rgb-0.4) * 1.4;
   vec3 qnorm = normalize(floor(aNorm*4.0+modnorm)*0.25) + vec3(0.001,0.0,0.0);

   vec3 tangent0 = normalize(cross(qnorm,vec3(0.0,1.0,0.0)));
   vec3 tangent1 = cross(qnorm,tangent0);
   vec2 uvdiffuse = vec2( dot(tangent0,aCo), dot(tangent1,aCo) ) * 0.160;
   
   // Patch local noise
   vec4 rgarbage = texture( uTexGarbage, uvdiffuse );

   // Colour blending
   float fblendclip = step(0.380,aColour.r + (rgarbage.r-0.5)*-1.740)*0.320;
   vec2 uvgradients = aUv + vec2( fblendclip, 0.0 );

   vfrag = texture( uTexGradients, uvgradients ).rgb;
   vfrag -= rgarbage.a*0.04;

   if( g_light_preview == 1 )
   {
      vfrag = vec3(0.5);
   }

   // Lighting
   vec3 halfview = uCamera - aWorldCo;
   float fdist = length( halfview );
   halfview /= fdist;

   vfrag = do_light_diffuse( vfrag, qnorm );
   vfrag = do_light_spec( vfrag, qnorm, halfview, 0.1 );
   vfrag = do_light_shadowing( vfrag );
   vfrag = apply_fog( vfrag, fdist );

   oColour = vec4(vfrag, 1.0 );
}