uniform sampler2D uTexGarbage;
uniform sampler2D uTexGradients;
uniform vec3 uCamera;

#include "light_clearskies_stddef.glsl"
#include "common_scene.glsl"
#include "motion_vectors_fs.glsl"

void main()
{
   compute_motion_vectors();

   vec3 vfrag = vec3(0.5,0.5,0.5);

   // ws modulation
   vec4 wgarbage = vec4(0.5,0.5,0.5,1.0);
   
   // Creating normal patches
   vec3 modnorm = (wgarbage.rgb-0.4) * 1.4;
   vec3 qnorm = normalize(floor(aNorm.xyz*4.0+modnorm)*0.25);
   qnorm += vec3(0.001,0.0,0.0);

   vec3 tangent0 = normalize(cross(qnorm,vec3(0.0,1.0,0.0)));
   vec3 tangent1 = cross(qnorm,tangent0);
   vec2 uvdiffuse = vec2( dot(tangent0,aCo), dot(tangent1,aCo) ) * 0.160;
   
   // Patch local noise
   vec4 rgarbage = texture( uTexGarbage, uvdiffuse );

   // Colour blending
   float fblendclip = step(0.380,aNorm.w + (rgarbage.r-0.5)*-1.740)*0.320;
   vec2 uvgradients = aUv + vec2( fblendclip, 0.0 );

   vfrag = texture( uTexGradients, uvgradients ).rgb;
   vfrag -= rgarbage.a*0.04;

   if( g_light_preview == 1 )
   {
      vfrag = vec3(0.5);
   }

   vfrag = scene_compute_lighting( vfrag, qnorm, aWorldCo );
   oColour = vec4(vfrag, 1.0);
}