uniform sampler2D uTexGarbage;
uniform sampler2D uTexGradients;
uniform vec3 uCamera;
uniform vec4 uColour;

#include "light_clearskies_stddef.glsl"
#include "common_scene.glsl"
#include "motion_vectors_fs.glsl"

float filtered_stripe( in float p, in float ddx, in float ddy )
{
   float w = max(abs(ddx), abs(ddy)) + 0.02;
   float i = (abs(fract((p-0.5*w)/2.0)-0.5)-abs(fract((p+0.5*w)/2.0)-0.5))/w;
   return 0.5 - i;
}

void main()
{
   compute_motion_vectors();

   vec3 vfrag = vec3(0.5,0.5,0.5);

   // ws modulation
   vec4 wgarbage = texture( uTexGarbage, aCo.xz * 0.015 );

   // Creating normal patches
   vec3 modnorm = (wgarbage.rgb-0.4) * 1.4;
   vec3 qnorm = normalize(floor(aNorm.xyz*4.0+modnorm)*0.25);
   qnorm += vec3(0.001,0.0,0.0);

   vec3 tangent0 = normalize(cross(qnorm,vec3(0.0,1.0,0.0)));
   vec3 tangent1 = cross(qnorm,tangent0);
   vec2 uvdiffuse = vec2( dot(tangent0,aCo), dot(tangent1,aCo) ) * 0.035;
   
   // Patch local noise
   vec4 rgarbage = texture( uTexGarbage, uvdiffuse );

   vfrag = pow(uColour.rgb,vec3(1.0/2.2));
   vfrag -= rgarbage.a*0.1;

   if( wgarbage.g < 0.1 )
      discard;

   float movep = (aUv.x + abs(aUv.y-0.5)*0.4 - g_realtime)*2.0;
   float stripe = filtered_stripe( movep, dFdx(movep), dFdy(movep) );
   vfrag *= 0.9+stripe*uColour.a; 

   if( g_light_preview == 1 )
   {
      vfrag = vec3(0.5);
   }

   // Lighting
   oColour = vec4( scene_compute_lighting( vfrag, qnorm, aWorldCo ), 1.0 );
}