uniform sampler2D uTexGarbage;
uniform sampler2D uTexMain;
uniform vec3 uCamera;
uniform vec4 uPlane;

uniform vec4 uPlayerPos; /* w: distance to uSpawnPos */
uniform vec4 uSpawnPos;  /* w: inverse distance to uPlayerPos */
uniform bool uAlphatest;
uniform vec4 uMapInfo; /* x: min, y: max, z: iso line amount */

#include "light_clearskies_stddef.glsl"
#include "common_scene.glsl"
#include "motion_vectors_fs.glsl"

vec2 smin( float a, float b, float k ){
   float h = max( k-abs(a-b), 0.0 )/k;
   float m = h*h*0.5;
   float s = m*k*(1.0/2.0);

   if( a < b )
      return vec2(a-s,m);
   else
      return vec2(b-s,1.0-m);
}

void main(){
   vec2 ssuv = gl_FragCoord.xy;
   vec3 vDither = vec3( dot( vec2( 171.0, 231.0 ), ssuv) );
   float dither = fract( vDither.g / 71.0 ) - 0.5;

   float dcam = (-8.0+distance( aCo, uCamera ))/4.0;
   float dy0 = aCo.y - uMapInfo.x;
   float dy1 = uMapInfo.y - aCo.y;

   if( min(min(dy0,dy1)*0.5, dcam) + dither < 0.51 ) 
      discard;

   compute_motion_vectors();

   vec3 vfrag = vec3(0.898,0.811,0.716);
   vec3 qnorm = aNorm.xyz;

   qnorm = normalize(floor(aNorm.xyz*4.0)*0.25);
   qnorm += vec3(0.001,0.0,0.0);

   if( uAlphatest ){
      vec4 vSample = texture( uTexMain, aUv );
      if( vSample.a < 0.5 )
         discard;
   }
   else{
   }

   vfrag = scene_compute_lighting( vfrag, qnorm, aWorldCo );
   
   // dots
   float d0 = distance( aCo, uPlayerPos.xyz )*2.0;
   float d1 = distance( aCo, uSpawnPos.xyz );

   vec2 dm = smin( d0, d1, 10.0 );
   float dd = fract(dm.x*0.2-g_realtime*0.5) * 
               max(0.0,1.0-dm.x*0.04) * 
               max(0.0,qnorm.y);
   vec3 emit = mix(vec3(1.0,0.0,0.0),vec3(0.0,1.0,0.0),dm.y)*dd;

   // line
   vec3 v0 = (uSpawnPos.xyz-uPlayerPos.xyz)*uSpawnPos.w;
   float t = clamp( dot(aCo-uPlayerPos.xyz,v0), 0.0, uPlayerPos.w );
   vec3 p0 = uPlayerPos.xyz + v0*t;
   float d3 = distance(p0,aCo);
   emit += vec3(fract(t*0.2-g_realtime+d3*0.2)*max(0.0,1.0-d3*0.2));

   vfrag += emit;

   if( uMapInfo.z > 0.0 ){
      float height = fract( aCo.y * 0.1 );
      float lg = 2.0*length(vec2(dFdx(height), dFdy(height)));
      vfrag *= 1.0f+(lg*0.2*uMapInfo.z);
   }

   oColour = vec4( vfrag, 1.0 );
   //oColour = vec4( vfrag, 1.0 );
}