//const vec3  DAYSKY_COLOUR   = vec3( 0.37, 0.54, 0.97 );
//const vec3  NIGHTSKY_COLOUR = vec3( 0.03, 0.05, 0.20 );
//const vec3  SUNSET_COLOUR   = vec3( 1.00, 0.32, 0.01 );
//const vec3  AMBIENT_COLOUR  = vec3( 0.13, 0.17, 0.35 );
//const vec3  SUNSET_AMBIENT  = vec3( 0.25, 0.17, 0.51 );
//const vec3  SUN_COLOUR      = vec3( 1.10, 0.89, 0.35 );

const float SUN_ANGLE       = 0.0001;
const float PI              = 3.14159265358979323846264;

//struct world_info
//{
//   float time,
//         time_of_day,
//         day_phase,
//         sunset_phase;
//   
//   vec3 sun_dir;
//};

vec3 rand33(vec3 p3)
{
	p3 = fract(p3 * vec3(.1031, .1030, .0973));
   p3 += dot(p3, p3.yxz+33.33);
   return fract((p3.xxy + p3.yxx)*p3.zyx);
}

float stars( vec3 rd, float rr, float size ){
   vec3 co = rd * rr;

   float a = atan(co.y, length(co.xz)) + 4.0 * PI;

   float spaces = 1.0 / rr;
   size = (rr * 0.0015) * fwidth(a) * 1000.0 * size;
   a -= mod(a, spaces) - spaces * 0.5;

   float count = floor(sqrt(pow(rr, 2.0) * (1.0 - pow(sin(a), 2.0))) * 3.0);
   
   float plane = atan(co.z, co.x) + 4.0 * PI;
   plane = plane - mod(plane, PI / count);

   vec2 delta = rand33(vec3(plane, a, 0.0)).xy;

   float level = sin(a + spaces * (delta.y - 0.5) * (1.0 - size)) * rr;
   float ydist = sqrt(rr * rr - level * level);
   float angle = plane + (PI * (delta.x * (1.0-size) + size * 0.5) / count);
   vec3 center = vec3(cos(angle) * ydist, level, sin(angle) * ydist);
   float star = smoothstep(size, 0.0, distance(center, co));
   return star;
}

float luminance( vec3 v )
{
   return dot( v, vec3(0.2126, 0.7052, 0.0722) );
}

vec3 clearskies_ambient( vec3 dir )
{
   float sun_azimuth  = g_sunset_phase * (dot( dir.xz, g_sun_dir.xz )*0.4+0.6);
   float sky_gradient = dir.y;
   
   /* Blend phase colours */
   vec3 ambient  = g_daysky_colour.rgb   * (g_day_phase-g_sunset_phase*0.1);
        ambient += g_sunset_colour.rgb   * (1.0-dir.y*0.5)*sun_azimuth;
        ambient += g_nightsky_colour.rgb * (1.0-g_day_phase);
   
   /* Add gradient */
        ambient -= sky_gradient * luminance(ambient)*1.6;
        
   return ambient;
}

vec3 clearskies_sky( vec3 ray_dir )
{
   ray_dir.y = abs( ray_dir.y );
   vec3 sky_colour  = clearskies_ambient( ray_dir );
   
   /* Sun */
   float sun_theta  = dot( ray_dir, g_sun_dir.xyz );
   float sun_size   = max( 0.0, sun_theta * 0.5 + 0.5 + SUN_ANGLE );
   float sun_shape  = pow( sun_size, 2000.0 );
         sun_shape += sun_size * max(g_sun_dir.y,0.0) * 0.5;
         
   vec3 sun_colour  = mix( vec3(1.0), g_sunset_colour.rgb, g_sunset_phase*0.5 );
        sun_colour *= sun_shape;

   
   float star = 0.0;
   float star_blend = 10.0*max(0.0,(1.0-g_day_phase*2.0));

   if( star_blend > 0.001 ){
      for( float j = 1.0; j <= 4.1; j += 1.0 ){
         float m = mix(0.6, 0.9, smoothstep(1.0, 2.0, j));
         star += stars( ray_dir, 1.94 * pow( 1.64, j ), m ) * (1.0/pow(4.0, j));
      }
   }
   
   vec3 composite = sky_colour + sun_colour + star*star_blend;
   return composite;
}

vec3 clearskies_lighting( vec3 normal, float shadow, vec3 halfview )
{
   float fresnel = 1.0 - abs(dot(normal,halfview));

   vec3  reflect_colour = mix( g_daysky_colour.rgb, g_sunset_colour.rgb, 
                               g_sunset_phase );

   vec3  sky_reflection = 0.5 * fresnel * reflect_colour;
   vec3  light_sun      = max( CLEARSKIES_LIGHT_DOT_MIN, 
                               dot(normal,g_sun_dir.xyz)*0.75+0.25
                           ) * g_sun_colour.rgb * g_day_phase;

   float scaled_shadow = max( shadow, 1.0 - max(g_sun_dir.y,0.0) );
   vec3 ambient = mix( g_ambient_colour.rgb, g_sunset_ambient.rgb, 
                       g_sunset_phase );

   return ambient + (light_sun + sky_reflection) * shadow;
}