layout (location = 0) out vec4 oColour;

layout (std140) uniform ub_world_lighting
{
   vec4 g_light_colours[3];
   vec4 g_light_directions[3];
   vec4 g_ambient_colour;

   vec4 g_water_plane;
   vec4 g_depth_bounds;
   float g_water_fog;
   int g_light_count;
   int g_light_preview;
   int g_shadow_samples;
};

uniform sampler2D g_world_depth;

// Standard diffuse + spec models
// ==============================

vec3 do_light_diffuse( vec3 vfrag, vec3 wnormal )
{
   vec3 vtotal = g_ambient_colour.rgb;

   for( int i=0; i<g_light_count; i++ )
   {
      vec3 vcolour = g_light_colours[i].rgb;
      vec3 vdir = g_light_directions[i].xyz;

      float flight = max(dot( vdir, wnormal )*0.75+0.25,0.0);
      vtotal += vcolour*flight;
   }

   return vfrag * vtotal;
}

vec3 do_light_spec( vec3 vfrag, vec3 wnormal, vec3 halfview, float fintensity )
{
   vec3 vcolour = g_light_colours[0].rgb;
   vec3 vdir = g_light_directions[0].xyz;

   vec3 specdir = reflect( -vdir, wnormal );
   float spec = pow(max(dot( halfview, specdir ), 0.0), 10.0);
   return vfrag + vcolour*spec*fintensity;
}

float world_depth_sample( vec3 pos )
{
   vec2 depth_coord = (pos.xz - g_depth_bounds.xy) * g_depth_bounds.zw; 
   return texture( g_world_depth, depth_coord ).r;
}

float shadow_sample( vec3 vdir )
{
   vec3 sample_pos = aWorldCo + vdir;
   float height_sample = world_depth_sample( sample_pos );

   float fdelta = height_sample - sample_pos.y;
   return clamp( fdelta, 0.1, 0.2 )-0.1;
}

vec3 do_light_shadowing_old( vec3 vfrag )
{
   float faccum = 0.0;
   faccum += shadow_sample( vec3( 0.0, 0.5, 0.0 ));
   faccum += shadow_sample( vec3( 2.0, 0.3, 0.0 ));
   faccum += shadow_sample( vec3( 3.0, 1.0, 0.0 ));
   faccum += shadow_sample( vec3( 5.0, 1.0, 0.0 ));
   faccum += shadow_sample( vec3( 0.0, 0.5, 0.0 )*1.5);
   faccum += shadow_sample( vec3( 2.0, 0.3, 0.0 )*1.5);
   faccum += shadow_sample( vec3( 3.0, 1.0, 0.0 )*1.5);
   faccum += shadow_sample( vec3( 5.0, 1.0, 0.0 )*1.5);
   return mix( vfrag, g_ambient_colour.rgb, faccum );
}

vec3 do_light_shadowing( vec3 vfrag )
{
   if( g_shadow_samples == 0 )
   {
      return vfrag;
   }

   float fspread = g_light_colours[0].w;
   vec3  vdir = g_light_directions[0].xyz;
   float flength = g_light_directions[0].w;

   float famt = 0.0;
   famt+=shadow_sample((vdir+vec3(-0.563, 0.550, 0.307)*fspread)*flength*0.1);
   famt+=shadow_sample((vdir+vec3( 0.808, 0.686, 0.346)*fspread)*flength*0.2);
   famt+=shadow_sample((vdir+vec3( 0.787, 0.074,-0.065)*fspread)*flength*0.3);
   famt+=shadow_sample((vdir+vec3(-0.593, 0.071,-0.425)*fspread)*flength*0.4);
   famt+=shadow_sample((vdir+vec3(-0.790,-0.933,-0.875)*fspread)*flength*0.5);
   famt+=shadow_sample((vdir+vec3( 0.807,-0.690, 0.472)*fspread)*flength*0.6);
   famt+=shadow_sample((vdir+vec3( 0.522,-0.379, 0.350)*fspread)*flength*0.7);
   famt+=shadow_sample((vdir+vec3( 0.483, 0.201, 0.306)*fspread)*flength*0.8);
   return mix( vfrag, g_ambient_colour.rgb, famt );
}

vec3 apply_fog( vec3 vfrag, float fdist )
{
   float dist = pow(fdist*0.0008,1.2);
   return mix( vfrag, vec3(0.55,0.76,1.0), min( 1.0, dist ) );
}