layout (location = 0) out vec4 oColour;

layout (std140) uniform ub_world_lighting
{
   vec4 g_light_colours[3];
   vec4 g_light_directions[3];
   vec4 g_ambient_colour;

   vec4 g_water_plane;
   vec4 g_depth_bounds;
   float g_water_fog;
   float g_time;
   int g_light_count;
   int g_light_preview;
   int g_shadow_samples;

   int g_debug_indices;
   int g_debug_complexity;

   // g_time ?

   //vec4 g_point_light_positions[32];
   //vec4 g_point_light_colours[32];
};

uniform sampler2D g_world_depth;

float world_depth_sample( vec3 pos )
{
   vec2 depth_coord = (pos.xz - g_depth_bounds.xy) * g_depth_bounds.zw; 
   return texture( g_world_depth, depth_coord ).r;
}

float world_water_depth( vec3 pos )
{
   vec2 depth_coord = (pos.xz - g_depth_bounds.xy) * g_depth_bounds.zw; 
   float ref_depth = g_water_plane.y*g_water_plane.w;
   return texture( g_world_depth, depth_coord ).g - ref_depth;
}

float shadow_sample( vec3 vdir )
{
   vec3 sample_pos = aWorldCo + vdir;
   float height_sample = world_depth_sample( sample_pos );

   float fdelta = height_sample - sample_pos.y;
   return clamp( fdelta, 0.1, 0.2 )-0.1;
}

vec3 apply_fog( vec3 vfrag, float fdist )
{
   float dist = pow(fdist*0.0008,1.2);
   return mix( vfrag, vec3(0.55,0.76,1.0), min( 1.0, dist ) );
}


// New lighting model

vec3 newlight_compute_ambient()
{
   return g_ambient_colour.rgb;
}

float newlight_compute_sun_shadow( vec3 dir )
{
   if( g_shadow_samples == 0 )
   {
      return 1.0;
   }

   float fspread = g_light_colours[0].w;
   vec3  vdir = dir;
   float flength = g_light_directions[0].w;

   float famt = 0.0;
   famt+=shadow_sample((vdir+vec3(-0.563, 0.550, 0.307)*fspread)*flength*0.1);
   famt+=shadow_sample((vdir+vec3( 0.808, 0.686, 0.346)*fspread)*flength*0.2);
   famt+=shadow_sample((vdir+vec3( 0.787, 0.074,-0.065)*fspread)*flength*0.3);
   famt+=shadow_sample((vdir+vec3(-0.593, 0.071,-0.425)*fspread)*flength*0.4);
   famt+=shadow_sample((vdir+vec3(-0.790,-0.933,-0.875)*fspread)*flength*0.5);
   famt+=shadow_sample((vdir+vec3( 0.807,-0.690, 0.472)*fspread)*flength*0.6);
   famt+=shadow_sample((vdir+vec3( 0.522,-0.379, 0.350)*fspread)*flength*0.7);
   famt+=shadow_sample((vdir+vec3( 0.483, 0.201, 0.306)*fspread)*flength*0.8);

   return 1.0 - famt;
}

vec3 newlight_compute_world_diffuse( vec3 wnormal )
{
   vec3 vtotal = g_ambient_colour.rgb;

   for( int i=0; i<g_light_count; i++ )
   {
      vec3 vcolour = g_light_colours[i].rgb;
      vec3 vdir = g_light_directions[i].xyz;

      float flight = max(dot( vdir, wnormal )*0.75+0.25,0.0);
      vtotal += vcolour*flight;
   }

   return vtotal;
}

vec3 newlight_compute_sun_spec( vec3 wnormal, vec3 halfview, float fintensity )
{
   vec3 vcolour = g_light_colours[0].rgb;
   vec3 vdir = g_light_directions[0].xyz;

   vec3 specdir = reflect( -vdir, wnormal );
   float spec = pow(max(dot( halfview, specdir ), 0.0), 10.0);
   return vcolour*spec*fintensity;
}

float newlight_specular( vec3 wnormal, vec3 dir, vec3 halfview, float exponent )
{
   vec3 specdir = reflect( -dir, wnormal );
   return pow(max(dot( halfview, specdir ), 0.0), exponent);
}

vec3 newlight_compute_quadratic( vec3 wnormal, vec3 halfview, 
                                 vec3 light_colour, vec3 light_pos )
{
   vec3 light_delta = (light_pos-aWorldCo) * 10.0;

   float quadratic = dot(light_delta,light_delta);
   float attenuation = 1.0f/( 1.0f + quadratic );
   attenuation *= max( 0.0, dot( normalize(light_delta), wnormal ) );

   return light_colour*attenuation;
}

vec3 newlight_compute_spot( vec3 wnormal, vec3 halfview, 
                            vec3 light_colour, vec3 light_pos,
                            vec4 light_dir )
{
   vec3 light_delta = (light_pos-aWorldCo) * 10.0;

   float quadratic = dot(light_delta,light_delta);
   float attenuation = 1.0f/( 1.0f + quadratic );

   light_delta = normalize( light_delta );
   attenuation *= max( 0.0, dot( light_delta, wnormal ) );

   float spot_theta = max( 0.0, dot( light_delta, -light_dir.xyz ) ),
            falloff = max( 0.0,( spot_theta - light_dir.w ) / (1.0-light_dir.w) );

   return light_colour*attenuation*falloff;
}