shaders/water_fast.fs

   1 out vec4 FragColor;
   2
   3 uniform sampler2D uTexDudv;
   4
   5 uniform float uTime;
   6 uniform vec3 uCamera;
   7 uniform float uSurfaceY;
   8
   9 uniform vec3 uShoreColour;
  10 uniform vec3 uOceanColour;
  11
  12 in vec4 aColour;
  13 in vec2 aUv;
  14 in vec3 aNorm;
  15 in vec3 aCo;
  16 in vec3 aWorldCo;
  17
  18 #include "common_world.glsl"
  19
  20 vec4 water_surf( vec3 halfview, vec3 vnorm, float depthvalue )
  21 {
  22    vec3 surface_tint = mix(uShoreColour, uOceanColour, depthvalue);
  23
  24    float ffresnel = pow(1.0-dot( vnorm, halfview ),5.0);
  25
  26    vec3 lightdir = vec3(0.95,0.0,-0.3);
  27    vec3 specdir = reflect( -lightdir, vnorm );
  28    float spec = pow(max(dot(halfview,specdir),0.0),20.0)*0.3;
  29
  30    return vec4( surface_tint + spec, max(min(depthvalue*4.0, 1.0),0.0) );
  31 }
  32
  33 void main()
  34 {
  35    // Surface colour composite
  36    float depthvalue = clamp( -world_depth_sample( aCo )*(1.0/25.0), 0.0, 1.0 );
  37
  38    vec2 world_coord = aCo.xz * 0.008;
  39    vec4 time_offsets = vec4( uTime ) * vec4( 0.008, 0.006, 0.003, 0.03 );
  40    vec4 dudva = texture( uTexDudv, world_coord + time_offsets.xy )-0.5;
  41    vec4 dudvb = texture( uTexDudv, world_coord *7.0 - time_offsets.zw )-0.5;
  42
  43    vec3 surfnorm = dudva.rgb + dudvb.rgb;
  44    surfnorm = normalize(vec3(0.0,1.0,0.0) + dudva.xyz*0.4 + dudvb.xyz*0.1);
  45
  46    // Foam
  47    float fband = fract( aCo.z*0.02+uTime*0.1+depthvalue*10.0 );
  48    fband = step( fband+dudva.a*0.8, 0.3 ) * max((1.0-depthvalue*4.0),0.0);
  49
  50    // Lighting
  51    vec3 halfview = -normalize( aCo-uCamera );
  52
  53    // Fog
  54    float fdist = pow(length( aCo.xz-uCamera.xz ) * 0.00047, 2.6);
  55
  56    // Composite
  57    vec4 vsurface = water_surf( halfview, surfnorm, depthvalue );
  58    vsurface.a -= fdist;
  59    FragColor = mix( vsurface, vec4(1.0,1.0,1.0,0.5), fband );
  60 }