shaders/water.fs

   1 out vec4 FragColor;
   2
   3 uniform sampler2D uTexMain;
   4 uniform sampler2D uTexDudv;
   5 uniform sampler2D uTexBack;
   6
   7 uniform vec2 uInvRes;
   8 uniform float uTime;
   9 uniform vec3 uCamera;
  10 uniform float uSurfaceY;
  11
  12 in vec4 aColour;
  13 in vec2 aUv;
  14 in vec3 aNorm;
  15 in vec3 aCo;
  16 in vec3 aWorldCo;
  17
  18 #include "common_world.glsl"
  19
  20 vec4 water_surf( vec3 halfview, vec3 vnorm, float depthvalue,
  21       vec4 beneath, vec4 above )
  22 {
  23    vec3 colour_shore = vec3( 0.21, 0.6, 0.8 );
  24    vec3 colour_ocean = vec3( 0.01, 0.1, 0.2 );
  25    vec3 surface_tint = mix(colour_shore, colour_ocean, depthvalue);
  26
  27    float ffresnel = pow(1.0-dot( vnorm, halfview ),5.0);
  28
  29    vec3 lightdir = vec3(0.95,0.0,-0.3);
  30    vec3 specdir = reflect( -lightdir, vnorm );
  31    float spec = pow(max(dot(halfview,specdir),0.0),20.0)*0.3;
  32
  33    // Depth
  34    float depthblend = pow( beneath.a,0.8 );
  35
  36    // Composite
  37    vec3 vsurface = mix(surface_tint, above.rgb, ffresnel );
  38    //vsurface += spec;
  39
  40    return vec4( vsurface,depthblend );
  41 }
  42
  43 void main()
  44 {
  45    // Create texture coords
  46    vec2 ssuv = gl_FragCoord.xy*uInvRes;
  47
  48    // Surface colour composite
  49    float depthvalue = clamp( -world_depth_sample( aCo )*(1.0/25.0), 0.0, 1.0 );
  50
  51    vec2 world_coord = aCo.xz * 0.008;
  52    vec4 time_offsets = vec4( uTime ) * vec4( 0.008, 0.006, 0.003, 0.03 );
  53    vec4 dudva = texture( uTexDudv, world_coord + time_offsets.xy )-0.5;
  54    vec4 dudvb = texture( uTexDudv, world_coord *7.0 - time_offsets.zw )-0.5;
  55
  56    vec3 surfnorm = dudva.rgb + dudvb.rgb;
  57    surfnorm = normalize(vec3(0.0,1.0,0.0) + dudva.xyz*0.4 + dudvb.xyz*0.1);
  58
  59    // Foam
  60    float fband = fract( aCo.z*0.02+uTime*0.1+depthvalue*10.0 );
  61    fband = step( fband+dudva.a*0.8, 0.3 ) * max((1.0-depthvalue*4.0),0.0);
  62
  63    // Lighting
  64    vec3 halfview = -normalize( aCo-uCamera );
  65
  66    // Sample textures
  67    vec4 above = texture( uTexMain, ssuv+ surfnorm.xz*0.2 );
  68    vec4 beneath = texture( uTexBack, ssuv );
  69
  70    // Fog
  71    float fdist = pow(length( aCo.xz-uCamera.xz ) * 0.00047, 2.6);
  72
  73    // Composite
  74    vec4 vsurface = water_surf( halfview, surfnorm, depthvalue, beneath, above );
  75    vsurface.a -= fdist;
  76    FragColor = mix( vsurface, vec4(1.0,1.0,1.0,0.5), fband );
  77 }