shaders/terrain.fs

   1 out vec4 FragColor;
   2
   3 uniform sampler2D uTexGarbage;
   4 uniform sampler2D uTexGradients;
   5 uniform vec3 uCamera;
   6
   7 in vec4 aColour;
   8 in vec2 aUv;
   9 in vec3 aNorm;
  10 in vec3 aCo;
  11 in vec3 aWorldCo;
  12
  13 #include "common_world.glsl"
  14
  15 void main()
  16 {
  17    vec3 vfrag = vec3(0.5,0.5,0.5);
  18
  19    // ws modulation
  20    vec4 wgarbage = texture( uTexGarbage, aCo.xz * 0.015 );
  21
  22    // Creating normal patches
  23    vec3 modnorm = (wgarbage.rgb-0.4) * 1.4;
  24    vec3 qnorm = normalize(floor(aNorm*4.0+modnorm)*0.25) + vec3(0.001,0.0,0.0);
  25    vec2 dir = normalize(qnorm.xz);
  26    vec2 uvdiffuse = aCo.xz * 0.02;
  27    uvdiffuse = mat2(dir.y, dir.x, -dir.x, dir.y) * uvdiffuse;
  28
  29    // Patch local noise
  30    vec4 rgarbage = texture( uTexGarbage, uvdiffuse );
  31
  32    // Colour blending
  33    float amtgrass = step(qnorm.y,0.6);
  34    float amtsand = min(max((aCo.y - 10.0) * -0.1,0.0)*qnorm.y,1.0);
  35    vec2 uvgradients = aUv + vec2( amtgrass*0.5 + rgarbage.a*0.4, 0.0 );
  36    vfrag = texture( uTexGradients, uvgradients ).rgb;
  37    vfrag = mix( vfrag, vec3(1.0,0.9,0.8)*0.9, amtsand );
  38
  39    qnorm = mix( qnorm, aNorm, amtsand );
  40
  41    if( g_light_preview == 1 )
  42    {
  43       vfrag = vec3(0.5);
  44    }
  45
  46    // Lighting
  47    vec3 halfview = uCamera - aCo;
  48    float fdist = length( halfview );
  49    halfview /= fdist;
  50
  51    vfrag = do_light_diffuse( vfrag, qnorm );
  52    vfrag = do_light_spec( vfrag, qnorm, halfview, 0.1 );
  53    vfrag = do_light_shadowing( vfrag );
  54    vfrag = apply_fog( vfrag, fdist );
  55
  56    FragColor = vec4(vfrag, 1.0 );
  57 }