shaders/terrain.fs

   1 uniform sampler2D uTexGarbage;
   2 uniform sampler2D uTexGradients;
   3 uniform vec3 uCamera;
   4 uniform vec3 uSandColour;
   5 uniform vec2 uBlendOffset;
   6
   7 in vec4 aColour;
   8 in vec2 aUv;
   9 in vec3 aNorm;
  10 in vec3 aCo;
  11 in vec3 aWorldCo;
  12
  13 #include "common_world.glsl"
  14 #include "motion_vectors_fs.glsl"
  15
  16 void main()
  17 {
  18    compute_motion_vectors();
  19
  20    // Colour
  21    // ------
  22    vec3 vfrag = vec3(0.5,0.5,0.5);
  23
  24    // ws modulation
  25    vec4 wgarbage = texture( uTexGarbage, aCo.xz * 0.015 );
  26
  27    // Creating normal patches
  28    vec3 modnorm = (wgarbage.rgb-0.4) * 1.4;
  29    vec3 qnorm = normalize(floor(aNorm*4.0+modnorm)*0.25) + vec3(0.001,0.0,0.0);
  30    vec2 dir = normalize(qnorm.xz);
  31    vec2 uvdiffuse = aCo.xz * 0.02;
  32    uvdiffuse = mat2(dir.y, dir.x, -dir.x, dir.y) * uvdiffuse;
  33
  34    // Patch local noise
  35    vec4 rgarbage = texture( uTexGarbage, uvdiffuse );
  36
  37    // Colour blending
  38    float amtgrass = step(qnorm.y,0.6);
  39    float amtsand = min(max((aCo.y - 10.0) * -0.1,0.0)*qnorm.y,1.0);
  40    vec2 uvgradients = aUv + vec2( amtgrass + rgarbage.a*0.8 )*uBlendOffset;
  41    vfrag = texture( uTexGradients, uvgradients ).rgb;
  42    vfrag = mix( vfrag, uSandColour, amtsand );
  43
  44    qnorm = mix( qnorm, aNorm, amtsand );
  45
  46    if( g_light_preview == 1 )
  47    {
  48       vfrag = vec3(0.5);
  49    }
  50
  51    // Lighting
  52    vec3 halfview = uCamera - aCo;
  53    float fdist = length( halfview );
  54    halfview /= fdist;
  55
  56    vfrag = do_light_diffuse( vfrag, qnorm );
  57    vfrag = do_light_spec( vfrag, qnorm, halfview, 0.1 );
  58    vfrag = do_light_shadowing( vfrag );
  59    vfrag = apply_fog( vfrag, fdist );
  60
  61    oColour = vec4(vfrag, 1.0 );
  62 }