shaders/terrain.fs

   1 uniform sampler2D uTexGarbage;
   2 uniform sampler2D uTexGradients;
   3 uniform vec3 uCamera;
   4 uniform vec3 uSandColour;
   5 uniform vec2 uBlendOffset;
   6 uniform vec3 uBoard0;
   7 uniform vec3 uBoard1;
   8
   9 in vec4 aColour;
  10 in vec2 aUv;
  11 in vec3 aNorm;
  12 in vec3 aCo;
  13 in vec3 aWorldCo;
  14
  15 #include "common_world.glsl"
  16 #include "motion_vectors_fs.glsl"
  17
  18 void main()
  19 {
  20    compute_motion_vectors();
  21
  22    // Colour
  23    // ------
  24    vec3 vfrag = vec3(0.5,0.5,0.5);
  25
  26    // ws modulation
  27    vec4 wgarbage = texture( uTexGarbage, aCo.xz * 0.015 );
  28
  29    // Creating normal patches
  30    vec3 modnorm = (wgarbage.rgb-0.4) * 1.4;
  31    vec3 qnorm = normalize(floor(aNorm*4.0+modnorm)*0.25) + vec3(0.001,0.0,0.0);
  32    vec2 dir = normalize(qnorm.xz);
  33    vec2 uvdiffuse = aCo.xz * 0.02;
  34    uvdiffuse = mat2(dir.y, dir.x, -dir.x, dir.y) * uvdiffuse;
  35
  36    // Patch local noise
  37    vec4 rgarbage = texture( uTexGarbage, uvdiffuse );
  38
  39    // Colour blending
  40    float amtgrass = step(qnorm.y,0.6);
  41    float amtsand = min(max((aCo.y - 10.0) * -0.1,0.0)*qnorm.y,1.0);
  42    vec2 uvgradients = aUv + vec2( amtgrass + rgarbage.a*0.8 )*uBlendOffset;
  43    vfrag = texture( uTexGradients, uvgradients ).rgb;
  44    vfrag = mix( vfrag, uSandColour, amtsand );
  45
  46    qnorm = mix( qnorm, aNorm, amtsand );
  47
  48    if( g_light_preview == 1 )
  49    {
  50       vfrag = vec3(0.5);
  51    }
  52
  53    // Lighting
  54    vec3 halfview = uCamera - aCo;
  55    float fdist = length( halfview );
  56    halfview /= fdist;
  57
  58    vfrag = do_light_diffuse( vfrag, qnorm );
  59    vfrag = do_light_spec( vfrag, qnorm, halfview, 0.1 );
  60    vfrag = do_light_shadowing( vfrag );
  61    vfrag = apply_fog( vfrag, fdist );
  62
  63    oColour = vec4(vfrag, 1.0 );
  64 }