shaders/scene_water_fast.fs

   1 uniform sampler2D uTexDudv;
   2
   3 uniform float uTime;
   4 uniform vec3 uCamera;
   5 uniform float uSurfaceY;
   6 uniform vec3 uBoard0;
   7 uniform vec3 uBoard1;
   8
   9 uniform vec3 uShoreColour;
  10 uniform vec3 uOceanColour;
  11
  12 #include "common_scene.glsl"
  13 #include "motion_vectors_fs.glsl"
  14
  15 vec4 water_surf( vec3 halfview, vec3 vnorm, float depthvalue )
  16 {
  17    vec3 surface_tint = mix(uShoreColour, uOceanColour, depthvalue);
  18
  19    float ffresnel = pow(1.0-dot( vnorm, halfview ),5.0);
  20
  21    vec3 lightdir = vec3(0.95,0.0,-0.3);
  22    vec3 specdir = reflect( -lightdir, vnorm );
  23    float spec = pow(max(dot(halfview,specdir),0.0),20.0)*0.3;
  24
  25    return vec4( surface_tint + spec, max(min(depthvalue*4.0, 1.0),0.0) );
  26 }
  27
  28 void main()
  29 {
  30    compute_motion_vectors();
  31
  32    // Surface colour composite
  33    float depthvalue = clamp( -world_water_depth( aCo )*(1.0/25.0), 0.0, 1.0 );
  34
  35    vec2 world_coord = aCo.xz * 0.008;
  36    vec4 time_offsets = vec4( uTime ) * vec4( 0.008, 0.006, 0.003, 0.03 );
  37    vec4 dudva = texture( uTexDudv, world_coord + time_offsets.xy )-0.5;
  38    vec4 dudvb = texture( uTexDudv, world_coord *7.0 - time_offsets.zw )-0.5;
  39
  40    vec3 surfnorm = dudva.rgb + dudvb.rgb;
  41    surfnorm = normalize(vec3(0.0,1.0,0.0) + dudva.xyz*0.4 + dudvb.xyz*0.1);
  42
  43    // Foam
  44    float fband = fract( aCo.z*0.02+uTime*0.1+depthvalue*10.0 );
  45    fband = step( fband+dudva.a*0.8, 0.3 ) * max((1.0-depthvalue*4.0),0.0);
  46
  47    // Lighting
  48    vec3 halfview = -normalize( aCo-uCamera );
  49
  50    // Fog
  51    float fdist = pow(length( aCo.xz-uCamera.xz ) * 0.00047, 2.6);
  52
  53    // Composite
  54    vec4 vsurface = water_surf( halfview, surfnorm, depthvalue );
  55    vsurface.a -= fdist;
  56    oColour = mix( vsurface, vec4(1.0,1.0,1.0,0.5), fband );
  57 }