shaders/scene_vertex_blend.fs

   1 uniform sampler2D uTexGarbage;
   2 uniform sampler2D uTexGradients;
   3 uniform vec3 uCamera;
   4 uniform vec3 uBoard0;
   5 uniform vec3 uBoard1;
   6
   7 in vec2 aUv;
   8 in vec4 aNorm;
   9 in vec3 aCo;
  10 in vec3 aWorldCo;
  11 flat in ivec4 aLights;
  12
  13 #include "common_scene.glsl"
  14 #include "motion_vectors_fs.glsl"
  15
  16 void main()
  17 {
  18    compute_motion_vectors();
  19
  20    vec3 vfrag = vec3(0.5,0.5,0.5);
  21
  22    // ws modulation
  23    vec4 wgarbage = vec4(0.5,0.5,0.5,1.0);
  24
  25    // Creating normal patches
  26    vec3 modnorm = (wgarbage.rgb-0.4) * 1.4;
  27    vec3 qnorm = normalize(floor(aNorm.xyz*4.0+modnorm)*0.25);
  28    qnorm += vec3(0.001,0.0,0.0);
  29
  30    vec3 tangent0 = normalize(cross(qnorm,vec3(0.0,1.0,0.0)));
  31    vec3 tangent1 = cross(qnorm,tangent0);
  32    vec2 uvdiffuse = vec2( dot(tangent0,aCo), dot(tangent1,aCo) ) * 0.160;
  33
  34    // Patch local noise
  35    vec4 rgarbage = texture( uTexGarbage, uvdiffuse );
  36
  37    // Colour blending
  38    float fblendclip = step(0.380,aNorm.w + (rgarbage.r-0.5)*-1.740)*0.320;
  39    vec2 uvgradients = aUv + vec2( fblendclip, 0.0 );
  40
  41    vfrag = texture( uTexGradients, uvgradients ).rgb;
  42    vfrag -= rgarbage.a*0.04;
  43
  44    if( g_light_preview == 1 )
  45    {
  46       vfrag = vec3(0.5);
  47    }
  48
  49    vfrag = scene_do_lighting( vfrag, qnorm );
  50    oColour = vec4(vfrag, 1.0);
  51 }