shaders/scene_route.fs

   1 uniform sampler2D uTexGarbage;
   2 uniform sampler2D uTexGradients;
   3 uniform vec3 uCamera;
   4 uniform vec4 uColour;
   5 uniform vec3 uBoard0;
   6 uniform vec3 uBoard1;
   7
   8 #include "common_scene.glsl"
   9 #include "motion_vectors_fs.glsl"
  10
  11 float filtered_stripe( in float p, in float ddx, in float ddy )
  12 {
  13    float w = max(abs(ddx), abs(ddy)) + 0.02;
  14    float i = (abs(fract((p-0.5*w)/2.0)-0.5)-abs(fract((p+0.5*w)/2.0)-0.5))/w;
  15    return 0.5 - i;
  16 }
  17
  18 void main()
  19 {
  20    compute_motion_vectors();
  21
  22    vec3 vfrag = vec3(0.5,0.5,0.5);
  23
  24    // ws modulation
  25    vec4 wgarbage = texture( uTexGarbage, aCo.xz * 0.015 );
  26
  27    // Creating normal patches
  28    vec3 modnorm = (wgarbage.rgb-0.4) * 1.4;
  29    vec3 qnorm = normalize(floor(aNorm.xyz*4.0+modnorm)*0.25);
  30    qnorm += vec3(0.001,0.0,0.0);
  31
  32    vec3 tangent0 = normalize(cross(qnorm,vec3(0.0,1.0,0.0)));
  33    vec3 tangent1 = cross(qnorm,tangent0);
  34    vec2 uvdiffuse = vec2( dot(tangent0,aCo), dot(tangent1,aCo) ) * 0.035;
  35
  36    // Patch local noise
  37    vec4 rgarbage = texture( uTexGarbage, uvdiffuse );
  38
  39    vfrag = pow(uColour.rgb,vec3(1.0/2.2));
  40    vfrag -= rgarbage.a*0.1;
  41
  42    if( wgarbage.g < 0.1 )
  43       discard;
  44
  45    float movep = (aUv.x + abs(aUv.y-0.5)*0.4 - g_realtime)*2.0;
  46    float stripe = filtered_stripe( movep, dFdx(movep), dFdy(movep) );
  47    vfrag *= 0.9+stripe*uColour.a;
  48
  49    if( g_light_preview == 1 )
  50    {
  51       vfrag = vec3(0.5);
  52    }
  53
  54    // Lighting
  55    vfrag = scene_compute_lighting( vfrag, qnorm, aWorldCo );
  56    oColour = vec4(vfrag, 1.0);
  57 }