shaders/scene_override.fs

   1 uniform sampler2D uTexGarbage;
   2 uniform sampler2D uTexMain;
   3 uniform vec3 uCamera;
   4 uniform vec4 uPlane;
   5
   6 uniform vec4 uPlayerPos; /* w: distance to uSpawnPos */
   7 uniform vec4 uSpawnPos;  /* w: inverse distance to uPlayerPos */
   8 uniform bool uAlphatest;
   9 uniform float uIsoAmt;
  10
  11 #include "common_scene.glsl"
  12 #include "motion_vectors_fs.glsl"
  13
  14 vec2 smin( float a, float b, float k ){
  15    float h = max( k-abs(a-b), 0.0 )/k;
  16    float m = h*h*0.5;
  17    float s = m*k*(1.0/2.0);
  18
  19    if( a < b )
  20       return vec2(a-s,m);
  21    else
  22       return vec2(b-s,1.0-m);
  23 }
  24
  25 void main(){
  26    vec2 ssuv = gl_FragCoord.xy;
  27    vec3 vDither = vec3( dot( vec2( 171.0, 231.0 ), ssuv) );
  28    float dither = fract( vDither.g / 71.0 ) - 0.5;
  29
  30    float dcam = (-8.0+distance( aCo, uCamera ))/4.0;
  31    if( min(aCo.y*0.5 + dither, dcam + dither) < 0.51 ) discard;
  32
  33    compute_motion_vectors();
  34
  35    vec3 vfrag = vec3(0.898,0.811,0.716);
  36    vec3 qnorm = aNorm.xyz;
  37
  38    qnorm = normalize(floor(aNorm.xyz*4.0)*0.25);
  39    qnorm += vec3(0.001,0.0,0.0);
  40
  41    if( uAlphatest ){
  42       vec4 vSample = texture( uTexMain, aUv );
  43       if( vSample.a < 0.5 )
  44          discard;
  45    }
  46    else{
  47    }
  48
  49    vfrag = scene_compute_lighting( vfrag, qnorm, aWorldCo );
  50
  51    // dots
  52    float d0 = distance( aCo, uPlayerPos.xyz )*2.0;
  53    float d1 = distance( aCo, uSpawnPos.xyz );
  54
  55    vec2 dm = smin( d0, d1, 10.0 );
  56    float dd = fract(dm.x*0.2-g_realtime*0.5) *
  57                max(0.0,1.0-dm.x*0.04) *
  58                max(0.0,qnorm.y);
  59    vec3 emit = mix(vec3(1.0,0.0,0.0),vec3(0.0,1.0,0.0),dm.y)*dd;
  60
  61    // line
  62    vec3 v0 = (uSpawnPos.xyz-uPlayerPos.xyz)*uSpawnPos.w;
  63    float t = clamp( dot(aCo-uPlayerPos.xyz,v0), 0.0, uPlayerPos.w );
  64    vec3 p0 = uPlayerPos.xyz + v0*t;
  65    float d3 = distance(p0,aCo);
  66    emit += vec3(fract(t*0.2-g_realtime+d3*0.2)*max(0.0,1.0-d3*0.2));
  67
  68    vfrag += emit;
  69
  70    if( uIsoAmt > 0.0 ){
  71       float height = fract( aCo.y * 0.1 );
  72       float lg = 2.0*length(vec2(dFdx(height), dFdy(height)));
  73       vfrag *= 1.0f+(lg*0.2*uIsoAmt);
  74    }
  75
  76    oColour = vec4( vfrag, 1.0 );
  77    //oColour = vec4( vfrag, 1.0 );
  78 }