shaders/common_world.glsl

   1 layout (std140) uniform ub_world_lighting
   2 {
   3    vec4 g_light_colours[3];
   4    vec4 g_light_directions[3];
   5    vec4 g_ambient_colour;
   6
   7    vec4 g_water_plane;
   8    vec4 g_depth_bounds;
   9    float g_water_fog;
  10    int g_light_count;
  11    int g_light_preview;
  12 };
  13
  14 uniform sampler2D g_world_depth;
  15
  16 // Standard diffuse + spec models
  17 // ==============================
  18
  19 vec3 do_light_diffuse( vec3 vfrag, vec3 wnormal )
  20 {
  21    vec3 vtotal = g_ambient_colour.rgb;
  22
  23    for( int i=0; i<g_light_count; i++ )
  24    {
  25       vec3 vcolour = g_light_colours[i].rgb;
  26       vec3 vdir = g_light_directions[i].xyz;
  27
  28       float flight = max(dot( vdir, wnormal )*0.75+0.25,0.0);
  29       vtotal += vcolour*flight;
  30    }
  31
  32    return vfrag * vtotal;
  33 }
  34
  35 vec3 do_light_spec( vec3 vfrag, vec3 wnormal, vec3 halfview, float fintensity )
  36 {
  37    vec3 vcolour = g_light_colours[0].rgb;
  38    vec3 vdir = g_light_directions[0].xyz;
  39
  40    vec3 specdir = reflect( -vdir, wnormal );
  41    float spec = pow(max(dot( halfview, specdir ), 0.0), 10.0);
  42    return vfrag + vcolour*spec*fintensity;
  43 }
  44
  45 float world_depth_sample( vec3 pos )
  46 {
  47    vec2 depth_coord = (pos.xz - g_depth_bounds.xy) * g_depth_bounds.zw;
  48    return texture( g_world_depth, depth_coord ).r;
  49 }
  50
  51 float shadow_sample( vec3 vdir )
  52 {
  53    vec3 sample_pos = aCo + vdir;
  54    float height_sample = world_depth_sample( sample_pos );
  55
  56    float fdelta = height_sample - sample_pos.y;
  57    return clamp( fdelta, 0.1, 0.2 )-0.1;
  58 }
  59
  60 vec3 do_light_shadowing_old( vec3 vfrag )
  61 {
  62    float faccum = 0.0;
  63    faccum += shadow_sample( vec3( 0.0, 0.5, 0.0 ));
  64    faccum += shadow_sample( vec3( 2.0, 0.3, 0.0 ));
  65    faccum += shadow_sample( vec3( 3.0, 1.0, 0.0 ));
  66    faccum += shadow_sample( vec3( 5.0, 1.0, 0.0 ));
  67    faccum += shadow_sample( vec3( 0.0, 0.5, 0.0 )*1.5);
  68    faccum += shadow_sample( vec3( 2.0, 0.3, 0.0 )*1.5);
  69    faccum += shadow_sample( vec3( 3.0, 1.0, 0.0 )*1.5);
  70    faccum += shadow_sample( vec3( 5.0, 1.0, 0.0 )*1.5);
  71    return mix( vfrag, g_ambient_colour.rgb, faccum );
  72 }
  73
  74 vec3 do_light_shadowing( vec3 vfrag )
  75 {
  76    float fspread = g_light_colours[0].w;
  77    vec3  vdir = g_light_directions[0].xyz;
  78    float flength = g_light_directions[0].w;
  79
  80    float famt = 0.0;
  81    famt+=shadow_sample((vdir+vec3(-0.563, 0.550, 0.307)*fspread)*flength*0.1);
  82    famt+=shadow_sample((vdir+vec3( 0.808, 0.686, 0.346)*fspread)*flength*0.2);
  83    famt+=shadow_sample((vdir+vec3( 0.787, 0.074,-0.065)*fspread)*flength*0.3);
  84    famt+=shadow_sample((vdir+vec3(-0.593, 0.071,-0.425)*fspread)*flength*0.4);
  85    famt+=shadow_sample((vdir+vec3(-0.790,-0.933,-0.875)*fspread)*flength*0.5);
  86    famt+=shadow_sample((vdir+vec3( 0.807,-0.690, 0.472)*fspread)*flength*0.6);
  87    famt+=shadow_sample((vdir+vec3( 0.522,-0.379, 0.350)*fspread)*flength*0.7);
  88    famt+=shadow_sample((vdir+vec3( 0.483, 0.201, 0.306)*fspread)*flength*0.8);
  89    return mix( vfrag, g_ambient_colour.rgb, famt );
  90 }
  91
  92 vec3 apply_fog( vec3 vfrag, float fdist )
  93 {
  94    float dist = pow(fdist*0.0008,1.2);
  95    return mix( vfrag, vec3(0.55,0.76,1.0), min( 1.0, dist ) );
  96 }