shaders/common_world.glsl

   1 layout (location = 0) out vec4 oColour;
   2
   3 // OpenGL wiki: Recommends do not use vec3 because of drivers. hence the v4s...
   4 layout (std140) uniform ub_world_lighting
   5 {
   6    vec4 g_cube_min;
   7    vec4 g_cube_inv_range;
   8
   9    vec4 g_water_plane;
  10    vec4 g_depth_bounds;
  11
  12    vec4 g_daysky_colour;
  13    vec4 g_nightsky_colour;
  14    vec4 g_sunset_colour;
  15    vec4 g_ambient_colour;
  16    vec4 g_sunset_ambient;
  17    vec4 g_sun_colour;
  18    vec4 g_sun_dir;
  19
  20    float g_water_fog;
  21    float g_time;
  22    float g_shadow_length;
  23    float g_shadow_spread;
  24
  25    float g_time_of_day;
  26    float g_day_phase;
  27    float g_sunset_phase;
  28
  29    int g_light_preview;
  30    int g_shadow_samples;
  31
  32    int g_debug_indices;
  33    int g_debug_complexity;
  34 };
  35
  36 uniform sampler2D g_world_depth;
  37 uniform samplerBuffer uLightsArray;
  38 uniform usampler3D uLightsIndex;
  39
  40 #include "light_clearskies.glsl"
  41
  42 float world_depth_sample( vec3 pos )
  43 {
  44    vec2 depth_coord = (pos.xz - g_depth_bounds.xy) * g_depth_bounds.zw;
  45    return texture( g_world_depth, depth_coord ).r;
  46 }
  47
  48 float world_water_depth( vec3 pos )
  49 {
  50    vec2 depth_coord = (pos.xz - g_depth_bounds.xy) * g_depth_bounds.zw;
  51    float ref_depth = g_water_plane.y*g_water_plane.w;
  52    return texture( g_world_depth, depth_coord ).g - ref_depth;
  53 }
  54
  55 float shadow_sample( vec3 vdir )
  56 {
  57    vec3 sample_pos = aWorldCo + vdir;
  58    float height_sample = world_depth_sample( sample_pos );
  59
  60    float fdelta = height_sample - sample_pos.y;
  61    return clamp( fdelta, 0.2, 0.4 )-0.2;
  62 }
  63
  64 float newlight_compute_sun_shadow( vec3 dir )
  65 {
  66    if( g_shadow_samples == 0 )
  67    {
  68       return 1.0;
  69    }
  70
  71    float fspread = g_shadow_spread;
  72    float flength = g_shadow_length;
  73
  74    float famt = 0.0;
  75    famt += shadow_sample((dir+vec3(-0.56,0.55, 0.30)*fspread)*flength*0.1);
  76    famt += shadow_sample((dir+vec3( 0.80,0.68, 0.34)*fspread)*flength*0.2);
  77    famt += shadow_sample((dir+vec3( 0.78,0.07,-0.06)*fspread)*flength*0.3);
  78    famt += shadow_sample((dir+vec3(-0.59,0.07,-0.42)*fspread)*flength*0.4);
  79
  80    //famt+=shadow_sample((dir+vec3(-0.790,-0.933,-0.875)*fspread)*flength*0.5);
  81    //famt+=shadow_sample((dir+vec3( 0.807,-0.690, 0.472)*fspread)*flength*0.6);
  82    //famt+=shadow_sample((dir+vec3( 0.522,-0.379, 0.350)*fspread)*flength*0.7);
  83    //famt+=shadow_sample((dir+vec3( 0.483, 0.201, 0.306)*fspread)*flength*0.8);
  84
  85    return 1.0 - famt;
  86 }
  87
  88 float newlight_specular( vec3 wnormal, vec3 dir, vec3 halfview, float exponent )
  89 {
  90    vec3 specdir = reflect( -dir, wnormal );
  91    return pow(max(dot( halfview, specdir ), 0.0), exponent);
  92 }
  93
  94 vec3 scene_apply_fog( vec3 vfrag, vec3 colour, float fdist )
  95 {
  96    float dist = pow(fdist*0.0010,0.78);
  97    return mix( vfrag, colour, min( 1.0, dist ) );
  98 }
  99
 100 vec3 rand33(vec3 p3)
 101 {
 102         p3 = fract(p3 * vec3(.1031, .1030, .0973));
 103    p3 += dot(p3, p3.yxz+33.33);
 104    return fract((p3.xxy + p3.yxx)*p3.zyx);
 105 }
 106
 107 vec3 scene_calculate_light( int light_index,
 108                             vec3 halfview, vec3 co, vec3 normal )
 109 {
 110    vec4 light_colour = texelFetch( uLightsArray, light_index+0 );
 111    vec4 light_co     = texelFetch( uLightsArray, light_index+1 );
 112    vec4 light_dir    = texelFetch( uLightsArray, light_index+2 );
 113
 114    vec3 light_delta = light_co.xyz-co;
 115    float dist2 = dot(light_delta,light_delta);
 116
 117    light_delta = normalize( light_delta );
 118
 119    float quadratic = dist2*100.0;
 120    float attenuation  = 1.0f/( 1.0f + quadratic );
 121          attenuation *= max( dot( light_delta, normal ), 0.0 );
 122
 123    float falloff = max( 0.0, 1.0-(dist2*light_co.w) );
 124
 125    if( light_dir.w < 0.999999 )
 126    {
 127       float spot_theta = max( 0.0, dot( light_delta, -light_dir.xyz ) );
 128       falloff *= max( 0.0, (spot_theta - light_dir.w) / (1.0-light_dir.w) );
 129    }
 130
 131    return light_colour.rgb * attenuation * falloff;
 132 }
 133
 134 vec3 scene_calculate_packed_light_patch( uint packed_index,
 135                                          vec3 halfview, vec3 co, vec3 normal )
 136 {
 137    uint light_count = packed_index & 0x3u;
 138
 139    vec3 l = vec3(0.0);
 140
 141    if( light_count >= 1u )
 142    {
 143       int index_0 = int( ((packed_index >>  2u) & 0x3ffu) * 3u );
 144       int index_1 = int( ((packed_index >> 12u) & 0x3ffu) * 3u );
 145       int index_2 = int( ((packed_index >> 22u) & 0x3ffu) * 3u );
 146
 147       l += scene_calculate_light( index_0, halfview, co, normal );
 148
 149       if( light_count >= 2u )
 150       {
 151          l += scene_calculate_light( index_1, halfview, co, normal );
 152
 153          if( light_count >= 3u )
 154          {
 155             l += scene_calculate_light( index_2, halfview, co, normal );
 156          }
 157       }
 158    }
 159
 160    return l;
 161 }
 162
 163 vec3 world_compute_lighting( vec3 diffuse, vec3 normal, vec3 co,
 164                              float light_mask )
 165 {
 166    if( g_light_preview == 1 )
 167       diffuse = vec3(0.75);
 168
 169    // Lighting
 170    vec3 halfview = uCamera - co;
 171    float fdist = length(halfview);
 172    halfview /= fdist;
 173
 174    float world_shadow = newlight_compute_sun_shadow( g_sun_dir.xyz
 175                                     * (1.0/(max(g_sun_dir.y,0.0)+0.2)) );
 176
 177    vec3 total_light = clearskies_lighting(
 178                            normal, min( light_mask, world_shadow ), halfview );
 179
 180    vec3 cube_coord = (co - g_cube_min.xyz) * g_cube_inv_range.xyz;
 181         cube_coord = floor( cube_coord );
 182
 183    if( g_debug_indices == 1 )
 184    {
 185       return rand33(cube_coord);
 186    }
 187
 188    if( g_debug_complexity == 1 )
 189    {
 190       ivec3 coord = ivec3( cube_coord );
 191       uvec4 index_sample = texelFetch( uLightsIndex, coord, 0 );
 192
 193       uint light_count = (index_sample.x & 0x3u) + (index_sample.y & 0x3u);
 194       return vec3( float(light_count)*(1.0/6.0), 0.0, 0.5 );
 195    }
 196
 197    // FIXME: this coord should absolutely must be clamped!
 198
 199    ivec3 coord = ivec3( cube_coord );
 200    uvec4 index_sample = texelFetch( uLightsIndex, coord, 0 );
 201
 202    total_light +=
 203       scene_calculate_packed_light_patch( index_sample.x,
 204                                           halfview, co, normal )
 205                                           * light_mask;
 206    total_light +=
 207       scene_calculate_packed_light_patch( index_sample.y,
 208                                           halfview, co, normal )
 209                                           * light_mask;
 210
 211    // Take a section of the sky function to give us a matching fog colour
 212
 213    vec3 fog_colour  = clearskies_ambient( -halfview );
 214    float sun_theta  = dot( -halfview, g_sun_dir.xyz );
 215    float sun_size   = max( 0.0, sun_theta * 0.5 + 0.5 );
 216    float sun_shape  = sun_size * max(g_sun_dir.y,0.0) * 0.5;
 217
 218    vec3 sun_colour  = mix( vec3(1.0), g_sunset_colour.rgb, g_sunset_phase*0.5 );
 219         sun_colour *= sun_shape;
 220
 221    fog_colour += sun_colour;
 222    return scene_apply_fog( diffuse * total_light, fog_colour, fdist );
 223 }