shaders/common_world.glsl

   1 layout (location = 0) out vec4 oColour;
   2
   3 layout (std140) uniform ub_world_lighting
   4 {
   5    vec4 g_light_colours[3];
   6    vec4 g_light_directions[3];
   7    vec4 g_ambient_colour;
   8
   9    vec4 g_water_plane;
  10    vec4 g_depth_bounds;
  11    float g_water_fog;
  12    int g_light_count;
  13    int g_light_preview;
  14    int g_shadow_samples;
  15
  16    vec4 g_point_light_positions[32];
  17    vec4 g_point_light_colours[32];
  18 };
  19
  20 uniform sampler2D g_world_depth;
  21
  22 float world_depth_sample( vec3 pos )
  23 {
  24    vec2 depth_coord = (pos.xz - g_depth_bounds.xy) * g_depth_bounds.zw;
  25    return texture( g_world_depth, depth_coord ).r;
  26 }
  27
  28 float world_water_depth( vec3 pos )
  29 {
  30    vec2 depth_coord = (pos.xz - g_depth_bounds.xy) * g_depth_bounds.zw;
  31    float ref_depth = g_water_plane.y*g_water_plane.w;
  32    return texture( g_world_depth, depth_coord ).g - ref_depth;
  33 }
  34
  35 float shadow_sample( vec3 vdir )
  36 {
  37    vec3 sample_pos = aWorldCo + vdir;
  38    float height_sample = world_depth_sample( sample_pos );
  39
  40    float fdelta = height_sample - sample_pos.y;
  41    return clamp( fdelta, 0.1, 0.2 )-0.1;
  42 }
  43
  44 float sdLine( vec3 p, vec3 a, vec3 b )
  45 {
  46   vec3 pa = p - a;
  47   vec3 ba = b - a;
  48
  49   float h = clamp( dot(pa,ba)/dot(ba,ba), 0.0, 1.0 );
  50   return length( pa - ba*h );
  51 }
  52
  53 vec3 apply_fog( vec3 vfrag, float fdist )
  54 {
  55    float dist = pow(fdist*0.0008,1.2);
  56    return mix( vfrag, vec3(0.55,0.76,1.0), min( 1.0, dist ) );
  57 }
  58
  59
  60 // New lighting model
  61
  62 vec3 newlight_compute_ambient()
  63 {
  64    return g_ambient_colour.rgb;
  65 }
  66
  67 float newlight_compute_sun_shadow()
  68 {
  69    if( g_shadow_samples == 0 )
  70    {
  71       return 1.0;
  72    }
  73
  74    float fspread = g_light_colours[0].w;
  75    vec3  vdir = g_light_directions[0].xyz;
  76    float flength = g_light_directions[0].w;
  77
  78    float famt = 0.0;
  79    famt+=shadow_sample((vdir+vec3(-0.563, 0.550, 0.307)*fspread)*flength*0.1);
  80    famt+=shadow_sample((vdir+vec3( 0.808, 0.686, 0.346)*fspread)*flength*0.2);
  81    famt+=shadow_sample((vdir+vec3( 0.787, 0.074,-0.065)*fspread)*flength*0.3);
  82    famt+=shadow_sample((vdir+vec3(-0.593, 0.071,-0.425)*fspread)*flength*0.4);
  83    famt+=shadow_sample((vdir+vec3(-0.790,-0.933,-0.875)*fspread)*flength*0.5);
  84    famt+=shadow_sample((vdir+vec3( 0.807,-0.690, 0.472)*fspread)*flength*0.6);
  85    famt+=shadow_sample((vdir+vec3( 0.522,-0.379, 0.350)*fspread)*flength*0.7);
  86    famt+=shadow_sample((vdir+vec3( 0.483, 0.201, 0.306)*fspread)*flength*0.8);
  87
  88    // player shadow
  89    float dist_to_player = max( 0.0, sdLine( aWorldCo, uBoard0, uBoard1 )-0.1 );
  90    float player_shadow = max( 1.0-dist_to_player*2.7, 0.0 );
  91    player_shadow *= player_shadow*player_shadow*player_shadow;
  92
  93    return 1.0 - max( player_shadow*0.8, famt );
  94 }
  95
  96 vec3 newlight_compute_world_diffuse( vec3 wnormal )
  97 {
  98    vec3 vtotal = g_ambient_colour.rgb;
  99
 100    for( int i=0; i<g_light_count; i++ )
 101    {
 102       vec3 vcolour = g_light_colours[i].rgb;
 103       vec3 vdir = g_light_directions[i].xyz;
 104
 105       float flight = max(dot( vdir, wnormal )*0.75+0.25,0.0);
 106       vtotal += vcolour*flight;
 107    }
 108
 109    return vtotal;
 110 }
 111
 112 vec3 newlight_compute_sun_spec( vec3 wnormal, vec3 halfview, float fintensity )
 113 {
 114    vec3 vcolour = g_light_colours[0].rgb;
 115    vec3 vdir = g_light_directions[0].xyz;
 116
 117    vec3 specdir = reflect( -vdir, wnormal );
 118    float spec = pow(max(dot( halfview, specdir ), 0.0), 10.0);
 119    return vcolour*spec*fintensity;
 120 }
 121
 122 vec3 newlight_compute_quadratic( vec3 wnormal, vec3 halfview,
 123                                  vec3 light_pos, vec3 light_colour )
 124 {
 125    vec3 light_delta = (light_pos-aWorldCo) * 10.0;
 126
 127    float quadratic = dot(light_delta,light_delta);
 128    float attenuation = 1.0f/( 1.0f + quadratic );
 129    attenuation *= max( 0.0, dot( normalize(light_delta), wnormal ) );
 130
 131    return light_colour*attenuation;
 132 }