uniform sampler2D uTexMain;
uniform sampler2D uTexDudv;
uniform sampler2D uTexBack;

uniform vec2 uInvRes;
uniform float uTime;
uniform vec3 uCamera;
uniform float uSurfaceY;
uniform vec3 uBoard0;
uniform vec3 uBoard1;

uniform vec3 uShoreColour;
uniform vec3 uOceanColour;

#include "common_scene.glsl"
#include "motion_vectors_fs.glsl"

vec4 water_surf( vec3 halfview, vec3 vnorm, float depthvalue, 
                 vec4 beneath, vec4 above )
{
   vec3 surface_tint = mix(uShoreColour, uOceanColour, depthvalue);

   float ffresnel = pow(1.0-dot( vnorm, halfview ),5.0);

   vec3 lightdir = vec3(0.95,0.0,-0.3);
   vec3 specdir = reflect( -lightdir, vnorm );
   float spec = pow(max(dot(halfview,specdir),0.0),20.0)*0.3;
   
   // Depth 
   float depthblend = pow( beneath.r, 0.8 );

   // Composite
   vec3 vsurface = mix(surface_tint, above.rgb, ffresnel );
   //vsurface += spec;

   return vec4( vsurface,depthblend );
}

void main()
{
   compute_motion_vectors();

   // Create texture coords
   vec2 ssuv = gl_FragCoord.xy*uInvRes;
   
   // Surface colour composite
   float depthvalue = clamp( -world_water_depth( aCo )*(1.0/25.0), 0.0, 1.0 );

   vec2 world_coord = aCo.xz * 0.008;
   vec4 time_offsets = vec4( uTime ) * vec4( 0.008, 0.006, 0.003, 0.03 );
   vec4 dudva = texture( uTexDudv, world_coord + time_offsets.xy )-0.5;
   vec4 dudvb = texture( uTexDudv, world_coord *7.0 - time_offsets.zw )-0.5;

   vec3 surfnorm = dudva.rgb + dudvb.rgb;
   surfnorm = normalize(vec3(0.0,1.0,0.0) + dudva.xyz*0.4 + dudvb.xyz*0.1);
   
   // Foam
   float fband = fract( aCo.z*0.02+uTime*0.1+depthvalue*10.0 );
   fband = step( fband+dudva.a*0.8, 0.3 ) * max((1.0-depthvalue*4.0),0.0);

   // Lighting
   vec3 halfview = -normalize( aCo-uCamera );

   // Sample textures
   vec4 above = texture( uTexMain, ssuv+ surfnorm.xz*0.2 );
   vec4 beneath = texture( uTexBack, ssuv );

   // Fog
   float fdist = pow(length( aCo.xz-uCamera.xz ) * 0.00047, 2.6);

   // Composite
   vec4 vsurface = water_surf( halfview, surfnorm, depthvalue, beneath, above );
   vsurface.a -= fdist;
   oColour = mix( vsurface, vec4(1.0,1.0,1.0,0.5), fband );
   oColour.rgb = scene_do_lighting( oColour.rgb, aNorm.xyz );
}